home *** CD-ROM | disk | FTP | other *** search
/ Aminet 1 (Walnut Creek) / Aminet - June 1993 [Walnut Creek].iso / usenet / sources / volume2 / fonts / fastext3.1 next >
Internet Message Format  |  1988-11-10  |  32KB
  1. Path: xanth!nic.MR.NET!umn-d-ub!rutgers!mit-eddie!bbn!ulowell!page
  2. From: page@swan.ulowell.edu (Bob Page)
  3. Newsgroups: comp.sources.amiga
  4. Subject: v02i059:  fasttext - speed up your text V3.0
  5. Message-ID: <10121@swan.ulowell.edu>
  6. Date: 10 Nov 88 02:34:25 GMT
  7. Organization: University of Lowell, Computer Science Dept.
  8. Lines: 924
  9. Approved: page@swan.ulowell.edu
  10.  
  11. Submitted-by: page@swan.ulowell.edu (Bob Page)
  12. Posting-number: Volume 2, Issue 59
  13. Archive-name: fonts/fasttext30.1
  14.  
  15. These routines utilize the blitter to speed up rendering of fonts of
  16. any height, and of 4-16 pixels in width.  Other fast text rendering
  17. routines only speed up rendering of 8 bit wide fonts.  This code can
  18. be linked in with your programs.  A skinny font is included so you
  19. can have more columns in a window.
  20.  
  21. [I lost the original submitter's address, sorry.  ..Bob]
  22.  
  23. #    This is a shell archive.
  24. #    Remove everything above and including the cut line.
  25. #    Then run the rest of the file through sh.
  26. #----cut here-----cut here-----cut here-----cut here----#
  27. #!/bin/sh
  28. # shar:    Shell Archiver
  29. #    Run the following text with /bin/sh to create:
  30. #    README
  31. #    Announcement
  32. #    8.uu
  33. #    wide.font.uu
  34. #    FastText.asm
  35. #    FastText.doc
  36. #    Ftest.c
  37. # This archive created: Wed Nov  9 21:22:54 1988
  38. cat << \SHAR_EOF > README
  39. FastText Copyright 1988 by Darren M. Greenwald
  40.  
  41. This is the first revision of my new FastText() code which
  42. can be linked in, and included within your programs.  These
  43. new routines utilize the blitter, and speed up rendering of
  44. fonts of any height, and of 4-16 pixels in width.  As far
  45. as I know, this is a first.  My own, and other fast text
  46. rendering routines only speed up rendering of 8 bit wide
  47. fonts.
  48.  
  49. This new Fast Text code is also somewhat easier to use then
  50. the previous two versions I released in 1978.
  51.  
  52. Oh, I went ahead, and added a font I created some time ago
  53. called WIDE.FONT.  Despite the name, WIDE.FONT is a
  54. skinnier 6 bit wide, 8 bit high Topaz style font.  It is a
  55. non-proportional font suitable for use with SetFont - using
  56. it effectively gives you more columns to work with, hence
  57. the name WIDE.FONT!
  58.  
  59. This new FastText() code is Copyrighted!  You must ask
  60. permission to utilize this code in any commercial, or
  61. shareware ventures.  Read the FastText.doc file for more
  62. information on how to contact me.
  63.  
  64. SHAR_EOF
  65. cat << \SHAR_EOF > Announcement
  66. This is my latest blitter based fast text rendering routines which are
  67. unique in that they speed up rendering of non-proportional fonts of any
  68. height, and from 4-16 pixels in width.    This stuff is written in assembly,
  69. and a test program written in Manx C is included to show off the speed
  70. difference between FastText(), and Text().  Source code is included - this
  71. file may be distributed freely, but permission is required to use these
  72. routines in commercial, and shareware products.
  73.  
  74. FastText Copyright 1988 by Darren M. Greenwald - Enjoy!
  75.  
  76. SHAR_EOF
  77. cat << \SHAR_EOF > 8.uu
  78.  
  79. begin 644 8
  80. M```#\P`````````!``````````````$-```#Z0```0UP`$YU```````````,^
  81. M`````!H/@``!````````````````````````````````````````````````J
  82. M```````````,`````!H``````\0`"`!#``8`!@`!```@?P```&X`2````JX`*
  83. M``````````")%"`$!!$``````'"''!/C/G'```@$''"/'./OG(OCLN(HG/'/%
  84. M'/HHHHHOG`#B`!`(`#`#`,"`H&```````$```````A&&@`')%'HJ!""-B```V
  85. M`(F(HC($(HHA!!`"(HG$HI$DHHB`DD(LHDHDHJHHHMHHD(`G`!`(`!`$@$``'
  86. M("```````$``````!!!+``'`/L)J"$!'"````IB!`E/(`HHA!"/A`KE$H(D$Z
  87. M((B`E$-NHDHDH"(HHG-A$$`M@`G+'%'$&E&`HB(O'+&M'O)(HHHOA!!```"`^
  88. M%'#&@$!/O@/@!/B"#)`O!''@`$``A*HG((G')OB`F$/KHG(G'"(HJB'"$"`H'
  89. M@`!-HK(N)&B`I"-HHDI&H$)(JE(I&!`@``"`/AF+`$!'"```",B$`O@HB(@@J
  90. M`"`!"+ODH(D$(HB(E$JIHD*E`B(E/G"$$!`@``'(H)/D)$B`N"*HHDI$G$)(6
  91. MJB(B!!!`````%/,I`""-B!`!$(B(HA(HB(A!!!/B`((DHI$D(HB(DDHHHD)DY
  92. MHB(G-MB(D`@@``)(HI($&$B`I"(HHG'$`DI'-E'$A!!```"`%"(F@!$``!`!0
  93. M('/OG#O'"'.!!`@$"'(O'./N'HOG,OHHG.'LG''B(HG/G`#@``&G'&G.!DG(&
  94. MHG(HG$!./#&B-HB/@A&``````````````"``````````````"```````````]
  95. M```````````@````````````/P``````/``'`````.!@``````,`````````E
  96. M``8`!@`&``P`!@`2``8`&``&`!X`!@`D``8`*@`&`#``!@`V``8`/``&`$(`.
  97. M!@!(``8`3@`&`%0`!@!:``8`8``&`&8`!@!L``8`<@`&`'@`!@!^``8`A``&J
  98. M`(H`!@"0``8`E@`&`)P`!@"B``8`J``&`*X`!@"T``8`N@`&`,``!@#&``8`Z
  99. MS``&`-(`!@#8``8`W@`&`.0`!@#J``8`\``&`/8`!@#\``8!`@`&`0@`!@$.A
  100. M``8!%``&`1H`!@$@``8!)@`&`2P`!@$R``8!.``&`3X`!@%$``8!2@`&`5``S
  101. M!@%6``8!7``&`6(`!@%H``8!;@`&`70`!@%Z``8!@``&`88`!@&,``8!D@`&/
  102. M`9@`!@&>``8!I``&`:H`!@&P``8!M@`&`;P`!@'"``8!R``&`<X`!@'4``8!@
  103. MV@`&`>``!@'F``8![``&`?(`!@'X``8!_@`&`@0`!@(*``8"$``&`A8`!@(<6
  104. M``8"(@`&`B@`!@(N``8"-``&`CH`!@)```8"0````^P````$``````````X`?
  105. 3``!$````7````&(````````#\CH`Q
  106. ``
  107. end
  108. size 1144
  109. SHAR_EOF
  110. cat << \SHAR_EOF > wide.font.uu
  111.  
  112. begin 644 wide.font
  113. M#P```5=)1$4O.```````````````````````````````````````````````@
  114. M`````````````````````````````````````````````````````````````
  115. M`````````````````````````````````````````````````````````````
  116. M`````````````````````````````````````````````````````````````
  117. M`````````````````````````````````````````````````````````````
  118. G````````````````````````````````````````````````"`!#+
  119. ``
  120. end
  121. size 264
  122. SHAR_EOF
  123. cat << \SHAR_EOF > FastText.asm
  124. *
  125. * Fast font Assembly sub-routines
  126. * 
  127. * Copyright 1988 by Darren M. Greenwald
  128. *
  129. * Rev. 3.0 9/27/88
  130. *
  131. * New blitter based routine to handle any size font
  132. *
  133. * This new routine relies on the brute force approach, and the blitter!
  134. * The font data is unpacked, and the masking, shifting, and target
  135. * addresses are pre-calculate for speed.
  136. *
  137. * This version of the fast text routines can render fonts of any height,
  138. * and of any size from 4-16 pixels wide.  Wider fonts, proportional fonts,
  139. * and styles are currently not supported.
  140. *
  141. * This routine is copyrighted, and freely distributable.  It may not be
  142. * used in any commercial product, shareware product, or commercial
  143. * publication  without permission.  It is permissible to release this file
  144. * as part of a public domain collection, or on a telecommunication service
  145. * as long as no "special charge" is made for this program;
  146. * "special charge" does not include standard charges for replication
  147. * of the media, or use of the system.
  148. *
  149. * The intent of the above should be clear - I did the work, and am giving
  150. * the code away for free.  While you may use it, you may not
  151. * profit from it.
  152. *
  153. * The previous fast text routines I released in 1987 were public domain
  154. * in every sense of the word.  In order to use these routines in a
  155. * commercial, or shareware venture, you must ask permission - at the most
  156. * I may ask in return that you include credit for the use of these
  157. * routines within your program's documentation, and/or free registration, or
  158. * a copy of the software you are developing.  In addition, I will provide
  159. * answers if you have any questions, and just maybe provide assistance
  160. * with modifying the routines to suit your needs.  All I ask is that you
  161. * ask!
  162. *
  163.  
  164.             XDEF     _InitFastText   ;Declare these labels visible to linker
  165.             XDEF     _FreeFastText
  166.             XDEF     _FastText
  167.  
  168.             XREF     _GfxBase
  169.             XREF     _LVOAllocMem
  170.             XREF     _LVOFreeMem
  171.             XREF     _LVOBltTemplate
  172.             XREF     _LVOText
  173.             XREF     _OwnBlitter
  174.             XREF     _DisownBlitter
  175.             XREF     _WaitBlit
  176.  
  177.             include  "SYS2:asm/exec/types.i"
  178.             include  "SYS2:asm/graphics/text.i"
  179.             include  "SYS2:asm/hardware/blit.i"
  180.             include  "SYS2:asm/hardware/custom.i"
  181.             include  "SYS2:asm/graphics/rastport.i"
  182.             CSEG
  183.  
  184. * ---------------------------------------------------------------------
  185. * Call this routine to free any memory allocated by InitFastText() 
  186. * below.
  187. * 
  188. * This is a safe routine - it can be called safely even if InitFastText()
  189. * fails.
  190. * ---------------------------------------------------------------------
  191. _FreeFastText:
  192.  
  193.             MOVE.L   FontData,D0       ;safety check for NULL ptr
  194.             BEQ      nodata
  195.             MOVEA.L  D0,A1             ;address of buffer to free
  196.             MOVE.L   FontSize,D0       ;size of buffer to free
  197.             MOVEA.L  $4,A6             ;ExecBase
  198.             JSR      _LVOFreeMem(A6)
  199.             CLR.L    FontData          ;set to NULL
  200.  
  201. nodata:
  202.  
  203.             MOVE.L   Imagebuf,D0
  204.             BEQ      nobuf             ;safety valve
  205.             MOVEA.L  D0,A1             ;address of buffer
  206.             MOVE.L   Imagesize,D0      ;size of working buffer
  207.             MOVEA.L  $4,A6
  208.             JSR      _LVOFreeMem(A6)
  209.             CLR.L    Imagebuf          ;set to NULL
  210.  
  211. nobuf:      RTS
  212.  
  213. * ---------------------------------------------------------------------
  214. * This routine does a few things for you.
  215. *
  216. * It checks to make sure the font size is within 4 bits wide, and 16
  217. * bits wide.  It also checks for PROP fonts.  Wider/thinner fonts, and
  218. * PROP fonts will cause this routine to fall through, and set up to
  219. * use Text() instead of the fast text routines.  This is transparent, so
  220. * you do not have to write additional code to handle anything if
  221. * the FastText() routine cannot be used.
  222. *
  223. * It allocates 2 chip ram buffers - one for the unpacked font data,
  224. * and the other for an image buffer to draw in.  The amount of space
  225. * required is calculated for you based on the font size per the pointer
  226. * to a TextFont structure which is passed via the stack.
  227. *
  228. * The font data is unpacked into words using an edge-to-edge model.
  229. * Extraneous bits are masked out, and the image data is left justified.
  230. *
  231. * The blitter masks, shifts, and destination addresses are pre-calcuated
  232. * for speed during rendering.
  233. *
  234. * An indirect function pointer is set-up based on the font width.  8 bit
  235. * wide fonts can be rendered faster then other fonts, so a special
  236. * blitter routine is devoted to handling 8 bit wide fonts.  Often this is
  237. * the most common font, so it makes sense to use this capability.
  238. *
  239. * ---------------------------------------------------------------------
  240.  
  241. font        EQU      04       ;stack offset
  242.  
  243. _InitFastText:
  244.  
  245.             MOVEA.L  font(SP),A2       ;address of a text font struct
  246.  
  247.             TST.L    tf_CharSpace(A2)  ;is this a prop font?
  248.             BNE      Initfailed
  249.  
  250.             CLR.L    D0
  251.  
  252.             MOVE.W   tf_XSize(A2),D0
  253.             MOVE.L   D0,XSize          ;save
  254.             CMP.W    #16,D0            ;check bounds of this
  255.             BHI      Initfailed
  256.  
  257.             MOVE.W   tf_YSize(A2),D0
  258.             MOVE.L   D0,YSize          ;save
  259.             CMP.W    #4,D0             ;check bounds of this
  260.             BLT      Initfailed
  261.  
  262.             MOVE.W   tf_Baseline(A2),Baseline
  263.  
  264. * allocate space for font imagery in unpacked word format - egads, this
  265. * uses a lot of memory, buts its the price to be paid I guess?
  266. *
  267.  
  268.             CLR.L    FontData          ;NULL by default
  269.             CLR.L    Imagebuf
  270.  
  271.             MULU     #512,D0           ;1 WORD per line * 256 chars
  272.             MOVE.L   D0,FontSize       ;save size of buffer
  273.             MOVE.L   #$10003,D1        ;MEMF_PUBLIC|MEMF_CHIP|MEMF_CLEAR
  274.             MOVEA.L  $4,A6
  275.             JSR      _LVOAllocMem(A6)  ;allocate space
  276.             TST.L    D0
  277.             BEQ      Initfailed        ;no memory for font data
  278.             MOVE.L   D0,FontData       ;save pointer
  279.  
  280. * allocate an image buffer for me to draw text in
  281.  
  282.             MOVE.L   YSize,D0
  283.             MULU     #128,D0           ;size of buffer calculated
  284.             MOVE.L   D0,Imagesize      ;save size
  285.             MOVEQ    #03,D1            ;MEMF_PUBLIC|MEMF_CHIP
  286.             MOVEA.L  $4,A6
  287.             JSR      _LVOAllocMem(A6)  ;allocate space
  288.             TST.L    D0
  289.             BEQ      NoImagebuf        ;no memory for font data
  290.             MOVE.L   D0,Imagebuf       ;save pointer
  291.  
  292. * unpack font data
  293.  
  294.             MOVEA.L  tf_CharLoc(A2),A0 ;location of offsets|width
  295.             MOVEA.L  tf_CharData(A2),A1
  296.             MOVEA.L  FontData,A3       ;where to put unpacked imagery
  297.  
  298.             CLR.L    D0
  299.             MOVE.B   tf_LoChar(A2),D0
  300.  
  301.             CLR.L    D1
  302.             MOVE.B   tf_HiChar(A2),D1
  303.  
  304.             SUB.B    D0,D1             ;total # of chars to unpack
  305.  
  306.             LSL.L    #1,D0             ;BYTE to WORD offset
  307.             ADDA.L   D0,A3             ;adjust pntr into image array now
  308.  
  309. dounpack:   MOVE.L   (A0)+,D0          ;fetch offset|width of each char
  310.  
  311.             CLR.L    D2
  312.             MOVE.W   D0,D2             ;width in D2
  313.  
  314.             SWAP     D0                ;pix offset in D0
  315.             CLR.L    D3
  316.             MOVE.W   D0,D3             ;word offset in D3
  317.  
  318.             AND.L    #$000F,D0
  319.             LSR.W    #4,D3             ;calc word offset
  320.             LSL.W    #1,D3
  321.  
  322.             CLR.L    D4                ;create mask
  323.             NOT.L    D4                ;all ones!
  324.             LSR.L    D2,D4             ;mask for this character
  325.             NOT.L    D4                ;invert mask
  326.  
  327.             MOVE.L   YSize,D5
  328.             SUBQ.W   #1,D5             ;-1 for DBF loop
  329.             CLR.L    D6
  330.  
  331. unpkfont:   MOVE.L   0(A1,D3.W),D7     ;create in D7
  332.  
  333.             LSL.L    D0,D7             ;left justify?
  334.             AND.L    D4,D7             ;mask lower bits
  335.             SWAP     D7                ;move to lower word
  336.             
  337.             MOVE.W   D7,0(A3,D6.L)     ;store
  338.  
  339.             ADD.W    tf_Modulo(A2),D3  ;adjust word offset
  340.             ADD.L    #512,D6
  341.  
  342.             DBF      D5,unpkfont
  343.  
  344.             ADDQ.L   #2,A3
  345.  
  346.             DBF      D1,dounpack
  347.  
  348. * set up arrays of pre-inited masks, shift values, and target addresses
  349.  
  350.             MOVE.W   #DEST+SRCB+SRCA+$FC,D7
  351.  
  352.             MOVE.L   XSize,D0
  353.             CMP.W    #08,D0            ;if equal to 8, use FASTEST mode!
  354.             BNE      docon0
  355.             MOVEQ    #00,D7            ;bltcon mask for bltcon1, or 0
  356.  
  357. docon0:
  358.  
  359.             MOVE.W   #255,D1           ;loop 256 times
  360.             MOVEQ    #00,D0            ;initial pixel offset
  361.  
  362.             MOVEA.L  #masks,A0
  363.             MOVEA.L  #shift,A1
  364.             MOVEA.L  #local,A2
  365.  
  366.             MOVEQ    #12,D5            ;shift value used later
  367.             MOVE.L   XSize,D6          ;used later
  368.  
  369. setup:      MOVE.L   D0,D2
  370.             MOVE.L   D2,D3
  371.  
  372.             LSR.W    #4,D2             ;calculate word offset
  373.             LSL.W    #1,D2             ; div by 16 * 2 for WORD offset
  374.  
  375.             AND.W    #$000F,D3         ;mask out all but pix offset
  376.  
  377.             MOVE.L   D2,D4
  378.             ADD.L    Imagebuf,D4       ;address to write this too
  379.             MOVE.L   D4,(A2)+          ;save address
  380.  
  381.             CLR.W    D4                ;create mask
  382.             NOT.W    D4                ;all ones!
  383.             LSR.W    D3,D4             ;mask for this character
  384.             NOT.W    D4                ;invert mask
  385.  
  386.             MOVE.W   D4,(A0)+          ;save mask
  387.  
  388.             LSL.W    D5,D3             ;shift for bltcon format
  389.             OR.W     D7,D3             ;depends of con0, or con1
  390.             MOVE.W   D3,(A1)+          ;save shift
  391.  
  392.             ADD.L    D6,D0
  393.             DBF      D1,setup
  394.  
  395. * determine maximum # of characters which can be drawn
  396.  
  397.             MOVE.L   XSize,D0
  398.             MOVE.L   #1008,D1
  399.             DIVU     D0,D1
  400.             MOVE.W   D1,Maxchars
  401.  
  402. * set-up blitter control functions based on font width
  403. * optimize for 8 bit wide fonts!
  404.  
  405.             CMP.W    #08,D0            ;if equal to 8, use FASTER mode!
  406.             BEQ      faster
  407.  
  408. slower:     MOVE.L   #Bltslow,OutPut
  409.             MOVEQ    #2,D0             ;width
  410.             BRA      setsize
  411.  
  412. faster:     MOVE.L   #Bltfast,OutPut
  413.             MOVEQ    #1,D0             ;width
  414.  
  415. setsize:    MOVE.L   YSize,D1          ;height
  416.             LSL.W    #6,D1             ;per blitter's delight
  417.             OR.W     D1,D0
  418.             MOVE.L   D0,blitsize
  419.  
  420.             RTS                        ;return TRUE
  421.  
  422.  
  423. * some error, return false
  424.  
  425. NoImagebuf: JSR      _FreeFastText     ;release alloced memory
  426.  
  427. * indicates regular system Text() may be used via these calls
  428.  
  429. Initfailed: CLR.L    OutPut            ;default to calling Text()
  430.             MOVEQ    #00,D0            ;return FALSE
  431.             RTS
  432.  
  433.  
  434. * ---------------------------------------------------------------------
  435. * Routines to render the line via the blitter!
  436. *
  437. * The blitter routines vary somewhat to optimize for speed!  8 bit wide
  438. * fonts are drawn much faster then other width fonts, but all fonts
  439. * are drawn much faster then Text()!  This makes sense to do this since
  440. * 8 bit wide fonts are the most common, and because I can make use of
  441. * some special blitter capabilities to speed the process along!
  442. * ---------------------------------------------------------------------
  443.  
  444.  
  445. rp          EQU      0004        ;stack offsets
  446. txbptr      EQU      rp+4
  447. count       EQU      txbptr+4
  448.  
  449. _FastText:  TST.L    OutPut
  450.             BEQ      CallText    ;if InitFastText() failed!
  451.  
  452.             MOVE.L   count(SP),D3
  453.             BEQ      Noway       ;why would you put a 0 for # of chars?
  454.             CMP.W    Maxchars,D3
  455.             BLS      getblitter
  456.             MOVE.W   Maxchars,D3 ;prevent overflow
  457.  
  458. * ok, I need that blitter for me only!
  459.  
  460. getblitter: SUBQ.W   #1,D3
  461.             JSR      _OwnBlitter
  462.             JSR      _WaitBlit
  463.  
  464. * set-up globals first
  465.  
  466.             MOVEA.L  txbptr(SP),A0
  467.             MOVEM.L  group,D4-D7/A1-A3
  468.  
  469. * call appropriate routine
  470.  
  471.             MOVEA.L  OutPut,A6
  472.             JSR      (A6)
  473.  
  474. * free blitter for someone else
  475.  
  476.             JSR      _DisownBlitter
  477.  
  478. * now blast this into the rastport!
  479.  
  480.             MOVEA.L  Imagebuf,A0       ;address of bitplane
  481.             MOVEQ    #00,D0            ;no offset
  482.             MOVE.L   #128,D1           ;src modulo
  483.             MOVEA.L  rp(SP),A1         ;rastport
  484.             CLR.L    D2
  485.             MOVE.W   rp_cp_x(A1),D2    ;x dest
  486.             ADD.W    D4,rp_cp_x(A1)    ;modify Move() position
  487.             CLR.L    D3
  488.             MOVE.W   rp_cp_y(A1),D3    ;dest y
  489.             SUB.W    Baseline,D3       ;- baseline of font
  490.             MOVE.L   YSize,D5          ;y size
  491.             MOVEA.L  _GfxBase,A6
  492.             JSR      _LVOBltTemplate(A6)
  493. Noway:      RTS
  494.  
  495.  
  496. * If InitFastText() failed, Text() may still be called via the
  497. * FastText() function.
  498. *
  499. * This makes use in a system which must use any size font easier to program.
  500. *
  501. CallText:   MOVEA.L  rp(SP),A1
  502.             MOVEA.L  txbptr(SP),A0
  503.             MOVE.L   count(SP),D0
  504.             MOVEA.L  _GfxBase,A6
  505.             JSR      _LVOText(A6)
  506.             RTS
  507.  
  508. * --------------------------------------------------
  509. * This is the faster logic for an 8 bit wide fonts!
  510. * --------------------------------------------------
  511. Bltfast:    MOVEA.L  #$dff000,A6       ;address of custom chips
  512.  
  513. * once set, these blitter registers dont change
  514.  
  515.             MOVE.W   #DEST+SRCB+SRCA+$FC,bltcon0(A6)
  516.             MOVE.W   #$FFFF,bltalwm(A6)   ;no last word mask
  517.             MOVE.W   #126,bltdmod(A6)
  518.             MOVE.W   #126,bltamod(A6)
  519.             MOVE.W   #510,bltbmod(A6)
  520.  
  521. * do as much set-up as possible while last blit is busy
  522.  
  523. blit8:      CLR.L    D0
  524.             MOVE.B   (A0)+,D0
  525.             BEQ      blt8done          ;terminate if NULL found
  526.  
  527.             LSL.W    #1,D0             ;cast to WORD offset
  528.             ADD.L    D5,D0             ;ready with pointer!
  529.  
  530.             ADD.L    D6,D4             ;add to width
  531.  
  532. Wait8:      BTST     #6,dmaconr(A6)    ;wait for last blit to complete
  533.             BNE      Wait8
  534.  
  535. * these blitter register change for each blit
  536.  
  537.             MOVE.L   D0,bltbpt(A6)     ;b src
  538.             MOVE.L   (A3),bltdpt(A6)   ;d src pntr
  539.             MOVE.L   (A3)+,bltapt(A6)  ;a src pntr
  540.             MOVE.W   (A1)+,bltafwm(A6) ;first word mask           
  541.             MOVE.W   (A2)+,bltcon1(A6) ;shift value for b
  542.  
  543.             MOVE.W   D7,bltsize(A6)    ;trigger blit
  544.             DBF      D3,blit8          ;char counter
  545.  
  546. blt8done:   RTS
  547.  
  548. * --------------------------------------------------
  549. * This is the slower mode for odd width fonts!
  550. * --------------------------------------------------
  551. Bltslow:    MOVEA.L  #$dff000,A6       ;address of custom chips
  552.             MOVEQ    #00,D1            ;address of destination here
  553.  
  554. * these registers dont change once set
  555.  
  556.             CLR.W    bltalwm(A6)       ;last word mask
  557.             CLR.W    bltcon1(A6)       ;no special modes
  558.             MOVE.W   #124,bltbmod(A6)  ;modulos
  559.             MOVE.W   #124,bltdmod(A6)
  560.  
  561. * this bit clears the image buffer as needed - speed optimized
  562. * thinner fonts will be drawn faster due to less hits
  563. * a hit is TRUE whenever the font imagery rolls over into the next word
  564.  
  565. doblits:    MOVE.W   (A1)+,D0
  566.             MOVE.L   (A3)+,D2
  567.             CMP.L    D2,D1
  568.             BEQ      dochars           ;working on same word
  569.  
  570. Waitlast:   BTST     #6,dmaconr(A6)    ;wait if needed
  571.             BNE      Waitlast
  572.  
  573.             MOVE.L   D2,D1             ;save for next time around
  574.  
  575.             MOVE.W   #124,bltamod(A6)
  576.             MOVE.W   D0,bltafwm(A6)
  577.             MOVE.L   D2,bltdpt(A6)     ;d src pntr
  578.             MOVE.L   D2,bltapt(A6)     ;a src pntr
  579.             MOVE.W   #DEST+SRCA+$F0,bltcon0(A6) ;d=a
  580.             MOVE.W   D7,bltsize(A6)    ;trigger blitter clear
  581.  
  582. * setup while last blit is busy
  583.  
  584. dochars:    CLR.L    D0
  585.             MOVE.B   (A0)+,D0
  586.             BEQ      bltodddone        ;terminate if NULL found
  587.  
  588.             LSL.W    #1,D0             ;cast to WORD offset
  589.             ADD.L    D5,D0             ;ready with pointer!
  590.  
  591.             ADD.L    D6,D4             ;add to width
  592.  
  593. Waitpack:   BTST     #6,dmaconr(A6)    ;wait for image packing
  594.             BNE      Waitpack
  595.  
  596. * set up blitter for character image move
  597.  
  598.             MOVE.W   #508,bltamod(A6)
  599.             MOVE.W   #$FFFF,bltafwm(A6)
  600.             MOVE.L   D0,bltapt(A6)     ;a src
  601.             MOVE.L   D2,bltbpt(A6)     ;b src pntr
  602.             MOVE.L   D2,bltdpt(A6)     ;d src pntr
  603.             MOVE.W   (A2)+,bltcon0(A6) ;shift value for a
  604.             MOVE.W   D7,bltsize(A6)    ;trigger blit
  605.  
  606.             DBF      D3,doblits        ;checks count
  607.  
  608. bltodddone: RTS
  609.  
  610.             RTS
  611.  
  612.  
  613.             DSEG
  614. * global variables I use - private!
  615.  
  616. Imagebuf:   dc.l     0     ;address of image buffer - part of above struct
  617. Imagesize:  ds.l     1     ;size of working buffer
  618.  
  619. FontSize:   ds.l     1     ;size of font data buffer
  620.  
  621. YSize:      ds.l     1     ;size of font height
  622.  
  623. Maxchars:   ds.w     1     ;Max chars which can be drawn at one time
  624.  
  625. Baseline:   ds.w     1     ;baseline of font
  626.  
  627. OutPut:     dc.l     0     ;address of function to call or NULL for Text()
  628.  
  629. masks:      ds.w     256   ;256 words for masks
  630. shift:      ds.w     256   ;256 shift values
  631. local:      ds.l     256   ;256 pointers to target location
  632.  
  633. * these are grouped for a good reason - the MOVEM instruction is used
  634. * by the rendering routines for efficiency - DONT play with the order
  635. * of these unless you know what you are doing.
  636.  
  637. group:      dc.l     0     ;0 to init width of line register
  638. FontData:   dc.l     0     ;address of font data
  639. XSize:      dc.l     0     ;size of font width
  640. blitsize:   dc.l     0     ;blit size value
  641.             dc.l     masks ;address of arrays
  642.             dc.l     shift
  643.             dc.l     local
  644.  
  645.  
  646.             END
  647.  
  648. SHAR_EOF
  649. cat << \SHAR_EOF > FastText.doc
  650. FastText revision 3.0 Copyright 1988 by Darren M. Greenwald
  651.  
  652. FastText is a copyrighted program.  It may be distributed freely, but it
  653. may NOT be sold/included in any way in any commercial, or shareware
  654. ventures without permission from the author.  It may be distributed in
  655. other public domain works so long as a notice of credit appears in the
  656. documentation.
  657.  
  658. FastText may be distributed as part of a public domain collection, and
  659. posted on telecommunication services so long as no additional charge is
  660. made above, and beyond the normal, and reasonable fees charged for
  661. the media, or use of system time.
  662.  
  663. If you would like permission to use this program in a commercial, or
  664. shareware venture, I can be contacted via the following methods:
  665.  
  666. On GEnie:               Send E-MAIL to DMG
  667. On Cute (714) 532-5698: Post a message in any forum to Darren Greenwald
  668. At Home:                (714) 545-6458
  669.  
  670. Including FastText in your programs -
  671.  
  672. FastText is written in assembly using the Manx Assembler.  Any changes
  673. needed to assemble this file with other assemblers is left up to you. 
  674. You need then only link the resulting object file with your code, and
  675. replace all calls too Text() with FastText().  In addition you must call the
  676. InitFastText() routine before calling FastText(), and finally call
  677. FreeFastText() as part of your cleanup/exit routine(s).  See the included
  678. FastText demo (Ftest.c) for an example of how easy this is to use.
  679.  
  680. In "C" format, the calls are defined like so:
  681.  
  682. InitFastText
  683. ------------
  684.  
  685. success=InitFastText(Font)
  686.  
  687. Inputs: Font - pointer to a TextFont structure
  688.  
  689. Return: TRUE, or FALSE
  690.  
  691. Description:
  692.  
  693. This routine does a number of things for you.  It checks to make sure that
  694. the font is a non-proportional font; it also checks to make sure the font
  695. is no less then 4 bits wide, but no more then 16 bits.  In any other case
  696. this routine returns FALSE.  Should this routine fail, you need not concern
  697. yourself too much.  In this case all calls to FastText() are automatically
  698. routed to call Text() instead.
  699.  
  700. Two CHIP RAM buffers are allocated based on the fonts height.  Fonts can be
  701. any height, but keep in mind that taller fonts use more memory.  One chip
  702. ram buffer is allocated for use as a buffer to draw the text imagery in, and
  703. the other is used to store the unpacked font data.
  704.  
  705. The font image data buffer requires 512 bytes * the font height.
  706.  
  707. The drawing buffer requires 128 bytes * the font height.
  708.  
  709. If this seems like a lot of memory, this is the trade off you make for the
  710. faster text rendering.  If the memory cannot be allocated, this routine
  711. will return FALSE, and all calls to FastText() are routed to call Text()
  712. instead.
  713.  
  714. Finally this routine upacks the font data, sets up the masks, blitter shift
  715. values, and some pointers to the image buffer.  Precalculating this
  716. stuff means that these calculations do not have to be done each time a line
  717. of text is rendered.
  718.  
  719. A special faster blitter routine is used for 8 bit wide fonts because 1.)
  720. Due to the way the blitter handles shifting it is possible to draw 8 bit
  721. wide fonts faster, and 2.) This works out well since 8 bit wide fonts are
  722. commonly used as the system font.
  723.  
  724. This routine should be called as part of your programs initialization
  725. procedures - it is your option to check for a return value since even if
  726. this fails, all calls to FastText() will automatically call Text() instead.
  727. This routine executes lickety-split; you won't have to wait "a moment" for
  728. the unpacking, and set-up to complete.
  729.  
  730. FastText
  731. --------
  732.  
  733. FastText(p,string,length)
  734.  
  735. Inputs: rp       - pointer to a rastport structure
  736.         string   - pointer to a string
  737.         length   - length of string to draw
  738.  
  739. Return: None
  740.  
  741. Description:
  742.  
  743. This call is very similar to Text().  It uses the exact same parameters
  744. as Text(), and behaves in a very similar manner.  You can set drawing
  745. colors (via SetAPen(), SetBPen()), drawing modes, etc.  The text position
  746. is set via the Move() function just like Text().
  747.  
  748. The X drawing position in the rastport is automatically incremented by the
  749. length (in pixels) of the string of text.
  750.  
  751. There are also some significant differences (speed of rendering included)!
  752.  
  753. Unlike Text() which draws a special image for non-defined characters in a
  754. font, FastText() draws undefined characters as blank spaces.  This could be
  755. changed if it causes anyone any problems.  I prefer it this way, but
  756. perhaps you may not?
  757.  
  758. FastText() does not currently support any font styles (e.g., bold,
  759. underline, italics).  This may be changed in the future.
  760.  
  761. The REVPATH flag is ignored.
  762.  
  763. FastText() treats NULL's as End of Line characters regardless of the length
  764. of string parameter.  This behavior can be changed if it causes anyone any
  765. problems.  I like it this way, but you may not.  Yes, this was intentional
  766. since it means I can call FastText(), and set the count to some large
  767. number rather then having to calculate the length of each string.  Text()
  768. on the other hand is terminated only by the length parameter, and will
  769. print NULL's as a non-printable character (usually a BOXY looking image).
  770.  
  771.  
  772. FreeFastText
  773. ------------
  774.  
  775. FreeFastText()
  776.  
  777. Inputs: None
  778.  
  779. Return: None
  780.  
  781. Description:
  782.  
  783. Frees memory allocated by InitFastText().  This routine can be called
  784. safely even if InitFastText() failed - in other words, it won't try to free
  785. memory which was never allocated.
  786.  
  787. ----------------------------------------------------------------------
  788.  
  789. Other notes:
  790.  
  791. It is very likely that this code is less then perfect.  Let the bug reports
  792. roll in!  Let me know, and I'll try to fix it ASAP.  Also hopefully I can
  793. further optimize the speed of the rendering routines.  In the future this
  794. whole thing may change anyway so that multiple fonts can be opened at the
  795. same time.SHAR_EOF
  796. cat << \SHAR_EOF > Ftest.c
  797. /*
  798.  * FastText() text demo by Darren M. Greenwald
  799.  * Copyright 1987 - FastText() REV 3.0
  800.  *
  801.  * "C" example of use.
  802.  * 
  803.  * You MUST assemble, and link in the FastText file in order for this to
  804.  * work!!!
  805.  * 
  806.  * Note that all work was done using Manx 3.6
  807.  * I leave it up to you to make adjustments as needed to work with your
  808.  * compiler/assembler.
  809.  *
  810.  * TURN OFF any text speed up programs if you really want to test this
  811.  * program right.  Programs such BLITZFONTS, and MicroSmith's FastFonts
  812.  * only speed up 8 bit wide fonts.  These routines allow you to gain
  813.  * a significant speed up for all size fonts, and the most speed up for
  814.  * 8 bit wide fonts.  Font widths other then 8 bits wide will vary in
  815.  * speed.  Thinner fonts will be drawn more quickly then wider fonts, but
  816.  * you can rest assured that the FastText() routines draw text faster then
  817.  * Text() - generally MUCH faster.
  818.  *
  819.  * If the font cannot be drawn faster (e.g., too wide, too thin, PROP
  820.  * font), then Text() is automatically called.
  821.  * 
  822.  */
  823.  
  824. #include <exec/types.h>
  825. #include <intuition/intuition.h>
  826. #include <exec/memory.h>
  827.  
  828. #define REV 0L
  829. #define SIZE 640L
  830.  
  831. struct IntuitionBase *IntuitionBase = NULL;
  832. struct GfxBase *GfxBase = NULL;
  833. struct Window *Window = NULL;
  834. struct RastPort *rp;
  835. struct Window *OpenWindow();
  836. void *OpenLibrary();
  837.  
  838. struct NewWindow NewWindow =
  839.    { 0,0,640,200,0,1,
  840.      CLOSEWINDOW,ACTIVATE|BORDERLESS|WINDOWDEPTH|WINDOWCLOSE|SMART_REFRESH,
  841.      NULL,NULL,
  842.      (UBYTE *)"FastText Demo Rev 3.0 - Close me!",
  843.      NULL,NULL,0,0,0,0,WBENCHSCREEN
  844.    };
  845.  
  846. void Cleanup();
  847.  
  848.  
  849. void main()
  850. {
  851.  
  852. ULONG MaxRows,fonthght,pixrow,i,j;
  853.  
  854.    IntuitionBase = (struct IntuitionBase *)
  855.       OpenLibrary("intuition.library",REV);
  856.    if(IntuitionBase == NULL) Cleanup();
  857.  
  858.    GfxBase = (struct GfxBase *)
  859.       OpenLibrary("graphics.library",REV);
  860.    if(GfxBase == NULL) Cleanup();
  861.  
  862.    Window = (struct Window *)
  863.       OpenWindow(&NewWindow);
  864.    if(Window == NULL) Cleanup();
  865.  
  866.    rp = Window->RPort;
  867.  
  868.  
  869. /*
  870.  * Wait till the close us down cause we are to lazy to mess with gadgets,
  871.  * or menus!
  872.  */
  873.  
  874.    Wait(1L<<Window->UserPort->mp_SigBit);
  875.  
  876.    SetAPen(rp,1L);
  877.    SetBPen(rp,0L);
  878.  
  879.    InitFastText(rp->Font); /* You could check for a TRUE/FALSE return */
  880.    
  881.       pixrow=32L;
  882.  
  883.       fonthght=(ULONG)rp->Font->tf_YSize;
  884.       MaxRows=(Window->Height-pixrow)/fonthght;
  885.  
  886.       SetWindowTitles(Window,"Drawing via Text()",NULL);
  887.  
  888.       for(i=1;i<MaxRows;i++)  /* do maximum # of times possible */
  889.       {
  890.          for(j=1;j<200;j++)   /* redraw line 300 times per row */
  891.          {
  892.             Move(rp,j+4L,pixrow);
  893.             Text(rp," This is 36 characters of SLOW text!",36L);
  894.          }
  895.          pixrow+=fonthght;
  896.       }
  897.  
  898. dox:  pixrow=32L;
  899.  
  900.       SetWindowTitles(Window,"Drawing via FastText()",NULL);
  901.  
  902.       for(i=1;i<MaxRows;i++)  /* do maximum # of times possible */
  903.       {
  904.          for(j=1;j<200;j++)   /* redraw line 300 times per row */
  905.          {
  906.             Move(rp,j+4L,pixrow);
  907.             FastText(rp," This is 36 characters of FAST text!",36L);
  908.          }
  909.          pixrow+=fonthght;
  910.       }
  911.  
  912.  
  913.    Cleanup();
  914. }
  915.  
  916. void Cleanup()
  917. {
  918.    FreeFastText();
  919.  
  920.    if(Window)           CloseWindow(Window);
  921.  
  922.    if(GfxBase)          CloseLibrary(GfxBase);
  923.    if(IntuitionBase)    CloseLibrary(IntuitionBase);
  924.  
  925.    exit(0L);
  926. }
  927.  
  928.  
  929. SHAR_EOF
  930. #    End of shell archive
  931. exit 0
  932. -- 
  933. Bob Page, U of Lowell CS Dept.  page@swan.ulowell.edu  ulowell!page
  934. Have five nice days.
  935.